План обмена данными контрагентов

В начало

План обмена данными контрагентов

Далее описан план обмена данными контрагентов в главной базе.

Рис. Структура справочника «Контрагенты» в главной базе

Рис. Структура и состав плана обмена «ОбменКонтрагентов»

Листинг. Модуль объекта плана обмена «ОбменКонтрагентов»

Процедура ПрочитатьСообщениеСИзменениями() Экспорт

Каталог = КаталогВременныхФайлов();

// Сформировать имя файла.

ИмяФайла = Каталог + ?(Прав(Каталог, 1) = "\", "", "\") + "Сообщение_ОбменКонтрагентов_" + СокрЛП(Ссылка.Код) + "-" +

СокрЛП(ПланыОбмена. ОбменКонтрагентов.ЭтотУзел().Код) + ".xml";

Файл = Новый Файл(ИмяФайла);

Если Не Файл.Существует() Тогда

Возврат;

КонецЕсли;

// *** Чтение документов XML

// Попытаться открыть файл.

ЧтениеXML = Новый ЧтениеXML;

Попытка

ЧтениеXML.ОткрытьФайл(ИмяФайла);

Исключение

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "Невозможно открыть файл обмена данными.";

Сообщение.Сообщить();

Возврат;

КонецПопытки;

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "-------- Загрузка из " + Строка(ЭтотОбъект) + " ------------";

Сообщение.Сообщить();

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = " – Считывается файл " + ИмяФайла;

Сообщение.Сообщить();

// Загрузить из найденного файла

// *** Инфраструктура сообщений.

ЧтениеСообщения = ПланыОбмена.СоздатьЧтениеСообщения();

// Читать заголовок сообщения обмена данными – файла XML.

ЧтениеСообщения.НачатьЧтение(ЧтениеXML);

// Сообщение предназначено не для этого узла.

Если ЧтениеСообщения.Отправитель <> Ссылка Тогда

ВызватьИсключение "Неверный узел";

КонецЕсли;

// Удаляем регистрацию изменений для узла отправителя сообщения

// *** Служба регистрации изменений.

ПланыОбмена.УдалитьРегистрациюИзменений(ЧтениеСообщения.Отправитель,

ЧтениеСообщения.НомерПринятого);

// Читаем данные из сообщения *** XML-сериализация.

Пока ВозможностьЧтенияXML(ЧтениеXML) Цикл

// Читаем очередное значение.

Данные = ПрочитатьXML(ЧтениеXML);

// Не переносим изменение, полученное в главный из неглавного,

// если есть регистрация изменения.

Если Не ЧтениеСообщения.Отправитель.Главный И

ПланыОбмена.ИзменениеЗарегистрировано(

ЧтениеСообщения.Отправитель, Данные) Тогда

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = " – Изменения отклонены";

Сообщение.Сообщить();

Продолжить;

КонецЕсли;

// Записать полученные данные.

Данные.ОбменДанными.Отправитель = ЧтениеСообщения.Отправитель;

Данные.ОбменДанными.Загрузка = Истина;

Данные.Записать();

КонецЦикла;

ЧтениеСообщения.ЗакончитьЧтение();

ЧтениеXML.Закрыть();

УдалитьФайлы(ИмяФайла);

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "-------- Конец загрузки ------------";

Сообщение.Сообщить();

КонецПроцедуры

Процедура ЗаписатьСообщениеСИзменениями() Экспорт

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "-------- Выгрузка в узел " + Строка(ЭтотОбъект) + " ------------";

Сообщение.Сообщить();

Каталог = КаталогВременныхФайлов();

// Сформировать имя временного файла.

ИмяФайла = Каталог + ?(Прав(Каталог, 1) = "\","", "\") + "Сообщение_ОбменКонтрагентов_" +

СокрЛП(ПланыОбмена. ОбменКонтрагентов.ЭтотУзел().Код) + "-" + СокрЛП(Ссылка.Код) + ".xml";

// Создать объект записи XML

// *** ЗаписьXML-документов

ЗаписьXML = Новый ЗаписьXML;

ЗаписьXML.ОткрытьФайл(ИмяФайла);

ЗаписьXML.ЗаписатьОбъявлениеXML();

// *** Инфраструктура сообщений

ЗаписьСообщения = ПланыОбмена.СоздатьЗаписьСообщения();

ЗаписьСообщения.НачатьЗапись(ЗаписьXML, Ссылка);

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = " Номер сообщения: " + ЗаписьСообщения.НомерСообщения;

Сообщение.Сообщить();

// Получить выборку измененных данных

// *** Механизм регистрации изменений

ВыборкаИзменений = ПланыОбмена.ВыбратьИзменения(ЗаписьСообщения.

Получатель,ЗаписьСообщения.НомерСообщения);

Пока ВыборкаИзменений.Следующий() Цикл

// Записать данные в сообщение *** XML-сериализация.

ЗаписатьXML(ЗаписьXML, ВыборкаИзменений.Получить());

КонецЦикла;

ЗаписьСообщения.ЗакончитьЗапись();

ЗаписьXML.Закрыть();

Сообщение = Новый СообщениеПользователю;

Сообщение.Текст = "-------- Конец выгрузки ------------";

Сообщение.Сообщить();

КонецПроцедуры

Рис. Форма узла плана обмена «Обмен контрагентов»

Листинг. Модуль формы узла плана обмена «ОбменКонтрагентов»

Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)

Если ЭтотОбъект.Ссылка = ПланыОбмена.ОбменКонтрагентов.ЭтотУзел() Тогда

ЭлементыФормы.Главный.Доступность = Ложь;

КонецЕсли;

КонецПроцедуры

Рис. Форма списка плана обмена

Листинг. Код модуля формы списка плана обмена

Процедура Кнопка1Нажатие(Элемент)

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| КонтрагентыИзменения.Ссылка

|ИЗ

| Справочник.Контрагенты.Изменения КАК КонтрагентыИзменения";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Узел = ЭлементыФормы.ПланОбменаСписок.ТекущаяСтрока;

Пока Выборка.Следующий() Цикл

ПланыОбмена.ЗарегистрироватьИзменения(Узел, Выборка.Ссылка);

КонецЦикла;

КонецПроцедуры

Функция ЭтоПредопределенныйУзел(Узел)

Возврат Узел = ПланыОбмена.ОбменКонтрагентов.ЭтотУзел();

КонецФункции

Процедура ПланОбменаСписокПриАктивизацииСтроки(Элемент)

Узел = ЭлементыФормы.ПланОбменаСписок.ТекущаяСтрока;

Если ЭтоПредопределенныйУзел(Узел) Тогда

ЭлементыФормы.ЗарегистрироватьИзменения.Доступность = Ложь;

Иначе

ЭлементыФормы.ЗарегистрироватьИзменения.Доступность = Истина;

КонецЕсли;

КонецПроцедуры

Рис. Форма обработки «ОбменДаннымиКонтрагентов»

Листинг. Модуль формы обработки «ОбменДаннымиКонтрагентов»

Процедура КнопкаВыполнитьНажатие(Кнопка)

ВыборкаУзлов = ПланыОбмена.ОбменКонтрагентов.Выбрать();

Пока ВыборкаУзлов.Следующий() Цикл

// Произвести обмен данными со всеми узлами, кроме текущего

Если ВыборкаУзлов.Ссылка <> ПланыОбмена.ОбменКонтрагентов.ЭтотУзел() Тогда

УзелОбъект = ВыборкаУзлов.ПолучитьОбъект();

УзелОбъект.ПрочитатьСообщениеСИзменениями();

УзелОбъект.ЗаписатьСообщениеСИзменениями();

КонецЕсли;

КонецЦикла;

КонецПроцедуры

Рис. Форма списка плана обмена в режиме «1С: Предприятие»

Листинг. Содержимое файла сообщения «Сообщение_ОбменКонтрагентов_ЦБ-ФЛ.xml»

<?xml version="1.0" encoding="UTF-8"?>

<v8msg:Message xmlns:v8msg="http://v8.1c.ru/messages">

<v8msg:Header>

<v8msg:ExchangePlan>ОбменКонтрагентов</v8msg:ExchangePlan>

<v8msg:To>ФЛ</v8msg:To>

<v8msg:From>ЦБ</v8msg:From>

<v8msg:MessageNo>2</v8msg:MessageNo>

<v8msg:ReceivedNo>0</v8msg:ReceivedNo>

</v8msg:Header>

<v8msg:Body>

<CatalogObject.Контрагенты>

<DeletionMark>false</DeletionMark>

<Description>Иванов ИИ</Description>

<Телефон>8-907-1234567</Телефон>

</CatalogObject.Контрагенты>

</v8msg:Body>

</v8msg:Message>

Далее идут настройки базы филиала.

Модуль объекта плана обмена аналогичен предыдущему.

Рис. Форма узла плана обмена в конфигурации филиала

Листинг. Модуль формы узла плана обмена в конфигурации филиала

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

Если Объект.Ссылка = ПланыОбмена.ОбменКонтрагентов.ЭтотУзел() Тогда

Элементы.Главный.Доступность = Ложь;

КонецЕсли;

КонецПроцедуры

Рис. Форма списка плана обмена в конфигурации филиала

Листинг. Модуль формы списка плана обмена в конфигурации филиала

&НаСервереБезКонтекста

Процедура ЗарегистрироватьИзмененияНаСервере(Узел)

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| КонтрагентыИзменения.Ссылка

|ИЗ

| Справочник.Контрагенты.Изменения КАК КонтрагентыИзменения";

Результат = Запрос.Выполнить();

Выборка = Результат.Выбрать();

Пока Выборка.Следующий() Цикл

ПланыОбмена.ЗарегистрироватьИзменения(Узел, Выборка.Ссылка);

КонецЦикла;

КонецПроцедуры

&НаКлиенте

Процедура ЗарегистрироватьИзменения(Команда)

Узел = Элементы.Список.ТекущаяСтрока;

ЗарегистрироватьИзмененияНаСервере(Узел);

КонецПроцедуры

&НаСервереБезКонтекста

Функция ЭтоПредопределенныйУзел(Узел)

Возврат Узел = ПланыОбмена.ОбменКонтрагентов.ЭтотУзел();

КонецФункции

&НаКлиенте

Процедура СписокПриАктивизацииСтроки(Элемент)

Если ЭтоПредопределенныйУзел(Элемент.ТекущаяСтрока) Тогда

Элементы.ЗарегистрироватьИзменения.Доступность = Ложь;

Иначе

Элементы.ЗарегистрироватьИзменения.Доступность = Истина;

КонецЕсли;

КонецПроцедуры

Рис. Форма обработки «ОбменДаннымиКонтрагентов»

Листинг. Модуль формы обработки в конфигурации филиала

&НаСервереБезКонтекста

Процедура ВыполнитьОбменНаСервере()

ВыборкаУзлов = ПланыОбмена.ОбменКонтрагентов.Выбрать();

Пока ВыборкаУзлов.Следующий() Цикл

// Произвести обмен данными со всеми узлами, кроме текущего

Если ВыборкаУзлов.Ссылка <> ПланыОбмена.ОбменКонтрагентов.ЭтотУзел() Тогда

УзелОбъект = ВыборкаУзлов.ПолучитьОбъект();

УзелОбъект.ПрочитатьСообщениеСИзменениями();

УзелОбъект.ЗаписатьСообщениеСИзменениями();

КонецЕсли;

КонецЦикла;

КонецПроцедуры

&НаКлиенте

Процедура ВыполнитьОбмен(Команда)

ВыполнитьОбменНаСервере();

КонецПроцедуры

Рис. Справочник «Контрагенты» после обмена данными:

в центральной базе «ЦБ» слева, в филиале «ФЛ» справа