Отчет по продажам и закупкам

Имеется два документа: «ПриходнаяНакладная» и «РасходнаяНакладная».

Нужно создать отчет, показывающий совокупные покупки и продажи по каждой номенклатуре.

Создаем новый объект в дереве объектов в разделе «Отчеты» и называем его просто – «ЗакупкиИПродажи».

Затем в свойствах объекта создаем форму отчета и добавляем кнопку «Сформировать», после чего перетаскиваем ее на командную панель.

Далее переходим в модуль формы отчета и создаем 2 процедуры: шаблон первой автоматически создаст мастер после того как мы перейдем в модуль формы через ранее созданную команду «Сформировать», а вторую создаем руками. После чего во второй процедуре вызываем контекстным меню конструктор запросов с обработкой результатов. В конструкторе запросов нужно вставить запрос по обработке документов, который можно проверить и отладить в консоли запросов.

Листинг 1. Исходный запрос, отлаженный в консоли запросов

ВЫБРАТЬ

Номенклатура,

СУММА (Закупки),

СУММА (Продажи)

ИЗ (ВЫБРАТЬ

Номенклатура,

Количество КАК Закупки,

0 Продажи

ИЗ Документ.ПриходнаяНакладная.Товары

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ

Номенклатура,

0 Закупки,

Количество КАК Продажи

ИЗ Документ.РасходнаяНакладная.Товары) КАК ВложенныйЗапрос

СГРУППИРОВАТЬ ПО

Номенклатура

После чего конструктор все обработает и даже создаст макет формы.

Рис. 1. Макет отчета по закупкам и продажам

Листинг 2

&НаКлиенте

Процедура Сформировать(Команда)

ТабДок = Новый ТабличныйДокумент;

СоздатьОтчет(ТабДок);

ТабДок.Показать();

КонецПроцедуры

&НаСервереБезКонтекста

Процедура СоздатьОтчет (ТабДок)

Макет = Отчеты.ЗакупкиИПродажи.ПолучитьМакет("Макет");

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| ВложенныйЗапрос.Номенклатура,

| СУММА(ВложенныйЗапрос.Закупки) КАК Закупки,

| СУММА(ВложенныйЗапрос.Продажи) КАК Продажи

|ИЗ

| (ВЫБРАТЬ

| ПриходнаяНакладнаяТовары.Номенклатура КАК Номенклатура,

| ПриходнаяНакладнаяТовары.Количество КАК Закупки,

| 0 КАК Продажи

| ИЗ

| Документ.ПриходнаяНакладная.Товары КАК ПриходнаяНакладнаяТовары

| ОБЪЕДИНИТЬ ВСЕ

| ВЫБРАТЬ

| РасходнаяНакладнаяТовары.Номенклатура,

| 0,

| РасходнаяНакладнаяТовары.Количество

| ИЗ

| Документ.РасходнаяНакладная.Товары КАК РасходнаяНакладнаяТовары)

| КАК ВложенныйЗапрос

|СГРУППИРОВАТЬ ПО

| ВложенныйЗапрос.Номенклатура";

Результат = Запрос.Выполнить();

ОбластьЗаголовок = Макет.ПолучитьОбласть("Заголовок");

ОбластьПодвал = Макет.ПолучитьОбласть("Подвал");

ОбластьШапкаТаблицы = Макет.ПолучитьОбласть("ШапкаТаблицы");

ОбластьПодвалТаблицы = Макет.ПолучитьОбласть("ПодвалТаблицы");

ОбластьДетальныхЗаписей = Макет.ПолучитьОбласть("Детали");

ТабДок.Очистить();

ТабДок.Вывести(ОбластьЗаголовок);

ТабДок.Вывести(ОбластьШапкаТаблицы);

ТабДок.НачатьАвтогруппировкуСтрок();

ВыборкаДетальныеЗаписи = Результат.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

ОбластьДетальныхЗаписей.Параметры.Заполнить(ВыборкаДетальныеЗаписи);

ТабДок.Вывести(ОбластьДетальныхЗаписей, ВыборкаДетальныеЗаписи.Уровень());

КонецЦикла;

ТабДок.ЗакончитьАвтогруппировкуСтрок();

ТабДок.Вывести(ОбластьПодвалТаблицы);

ТабДок.Вывести(ОбластьПодвал);

КонецПроцедуры

Рис. 2. Сформированный отчет

Как следует из отчета у нас сформировалась информация по трем видам номенклатуры. В столбце «Закупке» указано количество купленного товара, а в столбце «Продажи» – проданного.

ПРИМЕЧАНИЕ: данный отчет выполнен на версии 8.2.